#
# This is  a command that basically gives some specific information
# about an object without having to list all the attributes, in a format
# that I happen to personally use.  This one is up here because someone
# asked me how I converted flags() output to something understandable.
# See the Flags: line in DO_INFO, and ufunction u_matchflags.
#
-
&DO_INFO Tool=$info *:
  @pemit %#=Information for [setq(0,locate(%#,%0,*))][Name(%q0)](%q0):%r
  Type:%t[type(%q0)]%rOwner:%t[name(owner(%q0))]([owner(%q0)])%r
  Lock:%t[lock(%q0)] [u(u_parselock,%q0,)]%r
  [switch(type(%q0),EXIT,Destin,Loc)]:%t[name(loc(%q0))]([loc(%q0)])%r
  Money:%t[money(%q0)]%r
  Home:%t[name(home(%q0))]([home(%q0)])%r
  Flags:%t[trim(foreach(u_matchflag,flags(%q0)),b)]%r
  Parent:%t[name(parent(%q0))]([parent(%q0)])%r
  Sem:%t[get(%q0/semaphore)]%r
  [switch(exit(%q0),#-1,,*,Exits: [u(u_lexits,%q0)]%r)]
  Locks:%t[squish(iter(v(locklist),switch(lock(%q0/##),,,##:[lock(%q0/##)] [u(u_parselock,%q0,/##)])))]%r
  Size:%t[objmem(%q0)]%r
  Lattr:%t[words(lattr(%q0))]
-
&U_LEXITS Tool=iter(lexits(%0),first(name(##),;)([num(##)])%b%b)
-
&LOCKLIST Tool=EnterLock GiveLock LeaveLock LinkLock PageLock ParentLock \
  ReceiveLock TeloutLock TportLock UseLock UserLock
-
@lock/UseLock Tool=ISWIZ/1
-
&FLAGLIST Tool=ABODE(A) BUILDER(B) CHOWN_OK(C) DARK(D) FLOATING(F) GOING(G) \
  HAVEN(H) INHERIT(I) JUMP_OK(J) KEY(K) LINK_OK(L) MONITOR(M) NOSPOOF(N) \
  OPAQUE(O) QUIET(Q) STICKY(S) TRACE(T) UNFINDABLE(U) VISUAL(V) WIZARD(W) \
  STOP(X) PARENT_OK(Y) ZONE(Z) AUDIBLE(a) CONNECTED(c) DESTROY_OK(d) \
  ENTER_OK(e) HALTED(h) IMMORTAL(i) LIGHT(l) MYOPIC(m) PUPPET(p) TERSE(q) \
  ROBOT(r) SAFE(s) TRANSPARENT(t) SUSPECT(u) VERBOSE(v) SLAVE(x) CONTROL_OK(z) \
  COMMANDS($)
-
&FLAGLETTERS Tool=A B C D F G H I J K L M N O Q S T U V W X Y Z a c d e h i \
  l m p q r s t u v x z $
-
&U_MATCHFLAG Tool=extract(v(flaglist),member(v(flagletters),%0),1)%b
-
&U_PARSELOCK Tool=switch(lock(%0%1),*/*,get(%0/[first(lock(%0%1),/)]))
-
&ISWIZ Tool=[hasflag(%#,W)]
-
&U_ISPLAYER Tool=andflags(%0,Pc!r)
-
@set Tool=DARK
-
@set Tool=INHERIT
-
@set Tool=STICKY
-
@set Tool=SAFE
-
@set Tool=COMMANDS
-