#
# $Id: lumguzzle.pretty,v 1.3 1997/12/21 18:20:06 joi Exp joi $
# $Log: lumguzzle.pretty,v $
# Revision 1.3  1997/12/21 18:20:06  joi
# Added dbref references for quoting.
#
# Revision 1.2  1997/12/21 17:24:19  joi
# cleaned up source file.
#
# Revision 1.1  1997/12/03 22:07:14  joi
# Initial revision
#
# This file implements the drinking contents called 'lum guzzling'.
#
#
# /quote -w -0 !"unprettify <~/MyMush/lumguzzle.pretty"
#
#
# Object #159 is the boozer database.  This object contains a count of the
# lums guzzled for each player, and a flag for if they're currently drunk or not.
#
-
# &dbref_global_object me=#40
-
# &dbref_drunkards_db me=#159
-
# &dbref_functions_object me=#16
-
# &dbref_help_object me=#35
-
&do_lumguzzle [v(dbref_global_object)]=$+lumguzzle:
  @wait #159={
    @switch/first \
      [gte(
        setq(0,
	  rollopp(
	    switch(
	      setq(1,
		subdie(
		  u(#16/u_getspec,
		    %#,
		    Stamina/Lum$guzzling
		  ),
		  default(#159/lum_%#,0D)
		)
	      )
	      %q1,
	      -*,1D,
	      %q1
	    ),
	    1D,
	    2
	  )
	)
	%q0,
	0
      )]+[default(#159/drunk_%#,0)]
      =
      *+1,
      {
      @pemit %#=You can't guzzle, you're out cold on the floor!;
      @notify #159;
      },
      0+*,
      {
        @pemit *joi=%N rolled a %q1 %q0 lumguzzle result.;
	@pemit/contents %l=%N guzzles a pitcher of lum.;
	&lum_%# #159=adddie(1D,default(#159/lum_%#,0D));
	&drunk_%# #159=1;
	@wait 5={
	  @pemit/contents %l=%N passes out and falls off %p stool!;
	  @notify #159;
	};
      },
      1+0,
      {
        @pemit *joi=%N rolled a %q1 %q0 lumguzzle result.;
	@pemit/contents %l=%N guzzles a pitcher of lum.;
	&lum_%# #159=adddie(1D,default(#159/lum_%#,0D));
	@wait 5={
	  @pemit/contents %l=%N slams the empty pitcher back onto the bar.;
	  @notify #159;
	}
      };
    };
-
&do_soberup [v(dbref_global_object)]=$+soberup:
  @pemit %#=Magically you're sober again.;
  &lum_%# #159;
  &drunk_%# #159;
-
@startup #159=
  @drain me;
  @notify me;
-
# 
# This attribute is triggered by Mentor every X minutes to go through
# the drunkard's DB and reduce their drunk "damage".
#
# /quote -w -0 !"unprettify tr_wakie_wakie <~/MyMush/lumguzzle.pretty"
#
&tr_wakie_wakie #159=
  @dolist lattr(me/LUM_*) =
  {
     &lum_[setq(0,edit(##,LUM_,))]%q0 #159=
       setq(1,subdie(default(#159/lum_%q0,1D),1D))
       [switch(gt(%q1,0D),1,%q1,)]
       ;
     @pemit %q0=
       switch(
         default(me/drunk_%q0,0)+[default(me/lum_%q0,0D)],
	 1+*,You wake up from your stupor but are still quite thoroughly drunk.,
	 0+0D,You feel fine.,
	 0+*,You feel a little better.
       );
     &drunk_%q0 #159;
     @pemit me=Name(%q0) recovers.  [default(me/lum_%q0,No)] stamina/lum$guzzle reduction.;
  }
-
#
# Help Template entry.
# /quote -w -0 !"unprettify HELP_lumguzzle <~/MyMush/lumguzzle.pretty"
#
&HELP_lumguzzle [v(dbref_help_object)]=
################################################################################
"The syntax of the command is:
"  +lumguzzle
"
"Lum is an alcoholic beverage available throughout most of the known galaxy,
"although it is most popular in the Corellian sectors of space.  While only
"moderately intoxicating, and not prone to causing long-term damage as the
"stronger drinks do, it is still one of the most popular beverages used in
"drinking contests.
"
"Participants take turns downing entire pitchers of Lum.  The last one 
"standing wins. Lum guzzling is a test of one's strength/stamina/lum guzzling
"skills.  
"
"Continued in: lumguzzle2
-
#
# Help Template entry.
# /quote -w -0 !"unprettify HELP_lumguzzle2 <~/MyMush/lumguzzle.pretty"
#
&HELP_lumguzzle2 [v(dbref_help_object)]=
################################################################################
"After each pitcher is downed, a very easy difficulty check is made against 
"your strength/stamina/lum guzzling skill.  If you fail the check, you pass 
"out.  Lum Guzzling can be learned or taught, just like any other skill/spec.
"
"Each pitcher consumed temporarily reduces your lum guzzling skill by 1D.
"
"Once you pass out, you will not be able to consume any additional Lum until 
"you wake up again.  You will regain approx 4D of your strength/stamina/lum 
"guzzling skill each RL hour.
"
"See the RPG for additional ways drunkeness can affect you.
"
"For specific details, see the  "Leasiure Activies" chapter of the West Bend #15
"Galaxy Guide 9: Fragments from the Rim.
-