#
# $Id: finger.pretty,v 1.4 1997/12/22 04:27:21 joi Exp joi $
# $Log: finger.pretty,v $
# Revision 1.4  1997/12/22 04:27:21  joi
# Updated help formatting, added dbref object references.
#
# Revision 1.3  1997/12/09 02:31:32  joi
# Moved it from the global object to the wizzed object.
#
# Revision 1.2  1997/12/06 07:42:03  joi
# Added type test to prevent fingering objects.
#
# Revision 1.1  1997/12/06 07:34:34  joi
# Initial revision
#
#
# /quote -w -0 !"unprettify <~/MyMush/finger.pretty"
#
-
# &dbref_wizzed_object me=#19
-
# &dbref_help_ me=#35
-
&DO_FINGER [v(dbref_wizzed_object)]=$+finger *:
  @switch/first \
    setq(0,num(*[secure(%0)]))
    [type(%q0)]=
    PLAYER,
    @pemit %#=
    [repeat(-,78)]%r
    Finger information for [name(%q0)] ([default(%q0/alias,no aliases)])%r
    [repeat(-,78)]%r
    [Ljust(Fullname:,20)][default(%q0/fullname,name(%q0))]%r
    [switch(hasflag(%q0,Unfind),0,ljust(Location:,20)[name(loc(%q0))]%r)]
    [ljust(Email:,20)][default(%q0/public_email,none provided)]%r
    [switch(hasflag(%#,Wizard),1,[ljust(Private Email:,20)][default(%q0/private_email,none provided)]%r)]
    [ljust(WWW:,20)][default(%q0/public_www,none provided)]%r
    [ljust(Vacation:,20)][default(%q0/vacation,none provided)]%r
    [ljust(Last Connect:,20)]
      [switch(
        conn(%q0),
	-1,default(%q0/last,none provided),
	Name(%q0) has been connected since [convsecs(sub(secs(),conn(%q0)))].
      )]%r
    [ljust(Notes:,20)][default(%q0/public_notes,none provided)]%r
    [repeat(-,78)]%r,
    @pemit %#=That isn't a player!
-
#
# Help Template entry.
# /quote -w -0 !"unprettify HELP_finger <~/MyMush/finger.pretty"
#
&HELP_finger [v(dbref_help)]=
#80 characters wide..............................................................
"The syntax of the command is:
"  +finger <player>
"
"Examples:
"  +finger Chewbacca
"
"This command reveals a minimal amount of OOC information about the
"Character and/or the Typist.  This includes the last connect time,
"the public_email and public_www attributes, the full name, the aliases,
"the vacation attribute, and the public_notes attribute.
"
"If the player is not set UNFINDABLE, their location is also displayed.
"
"These items are provided to facilitate communication between Typists.
"
"Wizards will also see the private_email attribute.
-